Contents [show]
- Soek in Excel volgens verskeie kriteria
- Ons onttrek die 2de, 3de, ens. waardes met VLOOKUP
- Haal alle herhalings van die verlangde waarde op
- XNUMXD soektog volgens bekende ry en kolom
- Gebruik veelvuldige VLOOKUP's in een formule
- Dinamiese vervanging van data uit verskillende tabelle deur VLOOKUP en INDIREKTE gebruik
In die tweede deel van ons handleiding oor die funksie VPR (VLOOKUP) in Excel, sal ons 'n paar voorbeelde ontleed wat jou sal help om al die krag te rig VPR om die mees ambisieuse Excel-take op te los. Die voorbeelde veronderstel dat jy reeds 'n basiese kennis het van hoe hierdie kenmerk werk. Indien nie, sal jy dalk belangstel om met die eerste deel van hierdie tutoriaal te begin, wat die sintaksis en basiese gebruik verduidelik. VPR. Wel, kom ons begin.
Soek in Excel volgens verskeie kriteria
funksie VPR in Excel is 'n baie kragtige hulpmiddel om soektogte vir 'n bepaalde waarde in 'n databasis uit te voer. Daar is egter 'n beduidende beperking - die sintaksis daarvan laat jou toe om net vir een waarde te soek. Wat as jy volgens verskeie voorwaardes wil soek? Jy sal die oplossing hieronder vind.
Voorbeeld 1: Soek volgens 2 verskillende kriteria
Gestel ons het 'n lys van bestellings en ons wil vind Hoeveelheid goedere (Aantal), gebaseer op twee kriteria – Kliënt Naam (Kliënt) и Produknaam (Produk). Die saak word gekompliseer deur die feit dat elkeen van die kopers verskeie soorte goedere bestel het, soos uit die tabel hieronder gesien kan word:
gereelde funksie VPR sal nie in hierdie scenario werk nie, want dit sal die eerste waarde wat dit vind wat ooreenstem met die gegewe opsoekwaarde, terugstuur. Byvoorbeeld, as jy die hoeveelheid van 'n item wil weet Lekkers'deur die koper bestel Jeremy Hill, skryf die volgende formule:
=VLOOKUP(B1,$A$5:$C$14,3,FALSE)
=ВПР(B1;$A$5:$C$14;3;ЛОЖЬ)
– hierdie formule sal die resultaat gee 15ooreenstem met die produk appels, want dit is die eerste waarde wat ooreenstem.
Daar is 'n eenvoudige oplossing - skep 'n bykomende kolom waarin al die verlangde kriteria gekombineer kan word. In ons voorbeeld is dit die kolomme Kliënt Naam (Kliënt) и Produknaam (Produk). Moenie vergeet dat die saamgevoegde kolom altyd die linkerkantste kolom in die soekreeks moet wees nie, aangesien dit die linkerkolom is wat die funksie VPR kyk op wanneer jy 'n waarde soek.
So, jy voeg 'n hulpkolom by die tabel en kopieer die volgende formule oor al sy selle: =B2&C2. As jy wil hê dat die string meer leesbaar moet wees, kan jy die gekombineerde waardes met 'n spasie skei: =B2&» «&C2. Daarna kan jy die volgende formule gebruik:
=VLOOKUP("Jeremy Hill Sweets",$A$7:$D$18,4,FALSE)
=ВПР("Jeremy Hill Sweets";$A$7:$D$18;4;ЛОЖЬ)
or
=VLOOKUP(B1,$A$7:$D$18,4,FALSE)
=ВПР(B1;$A$7:$D$18;4;ЛОЖЬ)
Waar is die sel B1 bevat die saamgevoegde waarde van die argument lookup_value (opsoekwaarde) en 4 – Argument col_index_num (kolom_nommer), dit wil sê die nommer van die kolom wat die data bevat wat herwin moet word.
Voorbeeld 2: VLOOKUP deur twee kriteria met tabel wat op 'n ander blad bekyk word
As jy die hooftabel (Hooftabel) moet bywerk deur data van die tweede tabel (Opsoektabel) by te voeg, wat op 'n ander blad of in 'n ander Excel-werkboek geleë is, dan kan jy die verlangde waarde direk in die formule wat jy invoeg in die hooftabel.
Soos in die vorige voorbeeld, sal jy 'n hulpkolom in die Opsoektabel met die gekombineerde waardes benodig. Hierdie kolom moet die mees linkse kolom in die soekreeks wees.
Dus die formule met VPR kan so wees:
=VLOOKUP(B2&" "&C2,Orders!$A&$2:$D$2,4,FALSE)
=ВПР(B2&" "&C2;Orders!$A&$2:$D$2;4;ЛОЖЬ)
Hier bevat kolomme B en C onderskeidelik klantname en produkname en die skakel Bestellings!$A&$2:$D$2 definieer 'n tabel om in 'n ander blad op te soek.
Om die formule meer leesbaar te maak, kan jy die aansigreeks 'n naam gee, en dan sal die formule baie eenvoudiger lyk:
=VLOOKUP(B2&" "&C2,Orders,4,FALSE)
=ВПР(B2&" "&C2;Orders;4;ЛОЖЬ)
Vir die formule om te werk, moet die waardes in die linkerkantste kolom van die tabel waarna u kyk, gekombineer word op presies dieselfde manier as in die soekkriteria. In die figuur hierbo het ons die waardes u2bu2band gekombineer, plaas 'n spasie tussen hulle, op dieselfde manier as wat jy moet doen in die eerste argument van die funksie (BXNUMX& "" & CXNUMX).
Onthou! funksie VPR beperk tot 255 karakters, kan dit nie soek vir 'n waarde wat meer as 255 karakters lank is nie. Hou dit in gedagte en maak seker dat die lengte van die verlangde waarde nie hierdie limiet oorskry nie.
Ek stem saam dat die byvoeging van 'n hulpkolom nie die mees elegante en nie altyd aanvaarbare oplossing is nie. Jy kan dieselfde doen sonder die hulpkolom, maar dit sal 'n baie meer komplekse formule met 'n kombinasie van funksies vereis INDEKS (INDEKS) en MATCH (MEER BLOOTSTELLING).
Ons onttrek die 2de, 3de, ens. waardes met VLOOKUP
U weet dit al VPR kan slegs een ooreenstemmende waarde terugstuur, meer presies, die eerste een wat gevind is. Maar wat as hierdie waarde verskeie kere in die gekykte skikking herhaal word, en jy wil die 2de of 3de van hulle onttrek? Wat as alle waardes? Die probleem lyk ingewikkeld, maar die oplossing bestaan!
Gestel een kolom van die tabel bevat die name van die kliënte (Klantnaam), en die ander kolom bevat die produkte (Produk) wat hulle gekoop het. Kom ons probeer om die 2de, 3de en 4de items te vind wat deur 'n gegewe kliënt gekoop is.
Die maklikste manier is om 'n hulpkolom voor die kolom by te voeg Kliënt naam en vul dit met klantname met die herhalingsnommer van elke naam, byvoorbeeld, John Doe 1, John Doe 2 ens. Ons sal die truuk met nommering doen deur die funksie te gebruik COUNTIF (COUNTIF), aangesien die klante se name in kolom B is:
=B2&COUNTIF($B$2:B2,B2)
=B2&СЧЁТЕСЛИ($B$2:B2;B2)
Daarna kan jy die normale funksie gebruik VPRom die vereiste volgorde te vind. Byvoorbeeld:
- Vind 2de item wat deur die kliënt bestel is Dan Brown:
=VLOOKUP("Dan Brown2",$A$2:$C$16,3,FALSE)=ВПР("Dan Brown2";$A$2:$C$16;3;ЛОЖЬ) - Vind 3de item wat deur die kliënt bestel is Dan Brown:
=VLOOKUP("Dan Brown3",$A$2:$C$16,3,FALSE)=ВПР("Dan Brown3";$A$2:$C$16;3;ЛОЖЬ)
Trouens, jy kan 'n selverwysing as die opsoekwaarde in plaas van teks invoer, soos in die volgende figuur getoon:
As jy net op soek is na 2-e herhaling, kan jy dit sonder die hulpkolom doen deur 'n meer komplekse formule te skep:
=IFERROR(VLOOKUP($F$2,INDIRECT("$B$"&(MATCH($F$2,Table4[Customer Name],0)+2)&":$C16"),2,FALSE),"")
=ЕСЛИОШИБКА(ВПР($F$2;ДВССЫЛ("$B$"&(ПОИСКПОЗ($F$2;Table4[Customer Name];0)+2)&":$C16");2;ИСТИНА);"")
In hierdie formule:
- $F$2 – ’n sel wat die naam van die koper bevat (dit is onveranderd, let wel – die skakel is absoluut);
- $ B $ - kolom Kliënt naam;
- Table4 – Jou tafel (hierdie plek kan ook 'n gewone reeks wees);
- $ C16 – die eindsel van jou tabel of reeks.
Hierdie formule vind slegs die tweede ooreenstemmende waarde. As jy die oorblywende herhalings moet onttrek, gebruik die vorige oplossing.
As jy 'n lys van alle wedstryde benodig – die funksie VPR dit is nie 'n helper nie, aangesien dit net een waarde op 'n slag terugstuur – periode. Maar Excel het 'n funksie INDEKS (INDEX), wat hierdie taak maklik kan hanteer. Hoe so 'n formule sal lyk, sal jy in die volgende voorbeeld leer.
Haal alle herhalings van die verlangde waarde op
Soos bogenoem VPR kan nie alle duplikaatwaardes uit die geskandeerde reeks onttrek nie. Om dit te doen, benodig jy 'n effens meer komplekse formule, wat bestaan uit verskeie Excel-funksies, soos INDEKS (INDEKS), KLEIN (KLEIN) en rY (LINE)
Byvoorbeeld, die formule hieronder vind alle herhalings van die waarde van sel F2 in die reeks B2:B16 en gee die resultaat van dieselfde rye in kolom C terug.
{=IFERROR(INDEX($C$2:$C$16,SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3)),"")}
{=ЕСЛИОШИБКА(ИНДЕКС($C$2:$C$16;НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3));"")}
Voer hierdie skikkingsformule in in verskeie aangrensende selle, soos die selle F4: F8soos in die figuur hieronder getoon. Die aantal selle moet gelyk aan of groter wees as die maksimum moontlike aantal herhalings van die gesoekte waarde. Moenie vergeet om te klik nie Ctrl + Shift + Enterom die skikkingsformule korrek in te voer.
As jy belangstel om te verstaan hoe dit werk, kom ons duik bietjie in die besonderhede van die formule:
Deel 1:
IF($F$2=B2:B16,ROW(C2:C16)-1,"")
ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"")
$F$2=B2:B16 – vergelyk die waarde in sel F2 met elk van die waardes in die reeks B2:B16. As 'n passing gevind word, dan die uitdrukking STRING(C2:C16)-1 gee die nommer van die ooreenstemmende reël (waarde -1 laat jou toe om nie die koplyn in te sluit nie). As daar geen passings is nie, sal die funksie IF (IF) gee 'n leë string terug.
Funksie resultaat IF (IF) daar sal so 'n horisontale skikking wees: {1,"",3,"",5,"","","","","","",12,"","",""}
Deel 2:
ROW()-3
СТРОКА()-3
Hier is die funksie rY (LINE) dien as 'n bykomende teller. Aangesien die formule in selle F4:F9 gekopieer word, trek ons die getal af 3 van funksie resultaat om waarde te kry 1 in die sel F4 (reël 4, trek 3 af) om te kry 2 in die sel F5 (reël 5, trek 3 af) ensovoorts.
Deel 3:
SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3))
НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3))
funksie KLEIN (KLEIN) opbrengste n-o die kleinste waarde in die dataskikking. In ons geval word watter posisie (van die kleinste) om terug te keer bepaal deur die funksie rY (LYN) (sien Deel 2). Dus, vir 'n sel F4 funksie KLEIN({skikking};1) opbrengste 1de (kleinste) skikkingselement, dws 1. Vir sel F5 opbrengste 2de die kleinste element in die skikking, dit is 3, Ens.
Deel 4:
INDEX($C$2:$C$16,SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3))
ИНДЕКС($C$2:$C$16;НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3))
funksie INDEKS (INDEKS) gee bloot die waarde van 'n spesifieke sel in 'n skikking terug C2:C16. Vir sel F4 funksie INDEKS($C$2:$C$16) sal terugkeer appelsvir F5 funksie INDEKS($C$2:$C$16) sal terugkeer Lekkers' en so aan.
Deel 5:
IFERROR()
ЕСЛИОШИБКА()
Laastens plaas ons die formule binne die funksie IFERROR (IFERROR), want dit is onwaarskynlik dat jy tevrede sal wees met die foutboodskap #BY (#N/A) as die aantal selle waarin die formule gekopieer word minder is as die aantal duplikaatwaardes in die reeks wat bekyk word.
XNUMXD soektog volgens bekende ry en kolom
Om 'n XNUMXD soektog in Excel uit te voer, behels die soek na 'n waarde volgens 'n bekende ry- en kolomnommer. Met ander woorde, jy onttrek die selwaarde by die kruising van 'n spesifieke ry en kolom.
So, kom ons blaai na ons tabel en skryf 'n formule met 'n funksie VPR, wat inligting sal vind oor die koste van suurlemoene wat in Maart verkoop word.
Daar is verskeie maniere om 'n XNUMXD soektog uit te voer. Kyk na die opsies en kies die een wat jou die beste pas.
VLOOKUP en MATCH funksies
Jy kan 'n klomp funksies gebruik VPR (VLOOKUP) en MEER BLOOTSTELLING (MATCH) om die waarde by die kruising van die velde te vind Produknaam (string) en Maand (kolom) van die betrokke skikking:
=VLOOKUP("Lemons",$A$2:$I$9,MATCH("Mar",$A$1:$I$1,0),FALSE)
=ВПР("Lemons";$A$2:$I$9;ПОИСКПОЗ("Mar";$A$1:$I$1;0);ЛОЖЬ)
Die formule hierbo is 'n gereelde funksie VPR, wat soek na 'n presiese passing van die waarde "Suurlemoene" in selle A2 tot A9. Maar aangesien jy nie weet in watter kolom die Maart-verkope is nie, sal jy nie die kolomnommer vir die derde funksie-argument kan stel nie. VPR. In plaas daarvan word die funksie gebruik MEER BLOOTSTELLINGom hierdie kolom te definieer.
MATCH("Mar",$A$1:$I$1,0)
ПОИСКПОЗ("Mar";$A$1:$I$1;0)
Vertaal in menslike taal, beteken hierdie formule:
- Ons soek die karakters “Mar” – argument lookup_value (opsoek_waarde);
- Kyk in selle van A1 tot I1 – argument soek_skikking (opsoek_skikking);
- Wys presiese passing terug – argument passing_tipe (passing_tipe).
Die gebruik van 0 in die derde argument sê jy funksies MEER BLOOTSTELLING soek die eerste waarde wat presies ooreenstem met die waarde waarna jy soek. Dit is gelykstaande aan die waarde ONWAAR (ONWAAR) vir die vierde argument VPR.
Dit is hoe jy 'n tweerigtingsoekformule in Excel kan skep, ook bekend as tweedimensionele soektog of tweerigtingsoektog.
SUMPRODUCT funksie
funksie SUMPRODUCT (SUMPRODUK) gee die som van die produkte van die geselekteerde skikkings terug:
=SUMPRODUCT(($A$2:$A$9="Lemons")*($A$1:$I$1="Mar"),$A$2:$I$9)
=СУММПРОИЗВ(($A$2:$A$9="Lemons")*($A$1:$I$1="Mar");$A$2:$I$9)
INDEX en MATCH funksies
In die volgende artikel sal ek hierdie funksies in detail verduidelik, so vir nou kan jy net hierdie formule kopieer:
=INDEX($A$2:$I$9,MATCH("Lemons",$A$2:$A$9,0),MATCH("Mar",$A$1:$I$1,0))
=ИНДЕКС($A$2:$I$9;ПОИСКПОЗ("Lemons";$A$2:$A$9;0);ПОИСКПОЗ("Mar";$A$1:$I$1;0))
Benoemde reekse en die kruisingsoperateur
As jy nie van al daardie komplekse Excel-formules hou nie, sal jy dalk van hierdie visuele en onvergeetlike manier hou:
- Kies die tabel, maak die blad oop Formules (Formules) en klik Skep uit seleksie (Skep uit seleksie).
- Merk die blokkies Boonste ry (op die lyn hierbo) en Linker kolom (in die kolom aan die linkerkant). Microsoft Excel sal name toeken aan die reekse vanaf die waardes in die boonste ry en linkerkolom van jou sigblad. Nou kan jy hierdie name direk soek sonder om formules te skep.
- Skryf in enige leë sel =rynaam kolomnaam, byvoorbeeld soos volg:
=Suurlemoene Mrt
… of andersom:
=Mar Suurlemoene
Onthou dat die ry- en kolomname deur 'n spasie geskei moet word, wat in hierdie geval soos die kruisingsoperateur werk.
Wanneer jy 'n naam invoer, sal Microsoft Excel 'n nutswenk wys met 'n lys van ooreenstemmende name, net soos wanneer jy 'n formule invoer.
- Druk Tik en kyk na die resultaat
Oor die algemeen, watter van die bogenoemde metodes jy ook al kies, sal die resultaat van 'n tweedimensionele soektog dieselfde wees:
Gebruik veelvuldige VLOOKUP's in een formule
Dit gebeur dat die hooftabel en die opsoektabel nie 'n enkele kolom in gemeen het nie, en dit verhoed dat u die gewone funksie gebruik VPR. Daar is egter 'n ander tabel wat nie die inligting bevat waarin ons belangstel nie, maar 'n gemeenskaplike kolom met die hooftabel en die opsoektabel het.
Kom ons kyk na die volgende voorbeeld. Ons het 'n Hooftabel met 'n kolom SKU (nuut), waar jy 'n kolom met die ooreenstemmende pryse van 'n ander tabel wil byvoeg. Daarbenewens het ons 2 opsoektabelle. Die eerste een (Opsoektabel 1) bevat opgedateerde nommers SKU (nuut) en produkname, en die tweede (Opsoektabel 2) – produkname en ou nommers SKU (oud).
Om pryse vanaf die tweede opsoektabel by die hooftabel te voeg, moet jy 'n aksie uitvoer wat bekend staan as dubbel VPR of geneste VPR.
- Skryf 'n funksie VPR, wat die produknaam in die tabel vind Opsoektabel 1gebruik van SKU, as die verlangde waarde:
=VLOOKUP(A2,New_SKU,2,FALSE)=ВПР(A2;New_SKU;2;ЛОЖЬ)hier Nuwe_SKU – benoemde reeks $A:$B in die tabel Opsoektabel 1, 2 – dit is kolom B, wat die name van die goedere bevat (sien die prentjie hierbo)
- Skryf 'n formule om pryse uit 'n tabel in te voeg Opsoektabel 2 gebaseer op bekende produkname. Om dit te doen, plak die formule wat jy vroeër geskep het as die opsoekwaarde vir die nuwe funksie VPR:
=VLOOKUP(VLOOKUP(A2,New_SKU,2,FALSE),Price,3,FALSE)=ВПР(ВПР(A2;New_SKU;2;ЛОЖЬ);Price;3;ЛОЖЬ)hier Prys – benoemde reeks $A:$C in die tabel Opsoektabel 2, 3 is kolom C wat pryse bevat.
Die figuur hieronder toon die resultaat wat deur die formule wat ons geskep het, teruggestuur word:
Dinamiese vervanging van data uit verskillende tabelle deur VLOOKUP en INDIREKTE gebruik
Kom ons verduidelik eers wat ons bedoel met die uitdrukking “Dynamiese vervanging van data uit verskillende tabelle” om seker te maak dat ons mekaar reg verstaan.
Daar is situasies wanneer daar verskeie velle met data van dieselfde formaat is, en dit is nodig om die nodige inligting uit 'n sekere blad te onttrek, afhangende van die waarde wat in 'n gegewe sel ingevoer word. Ek dink dit is makliker om dit met 'n voorbeeld te verduidelik.
Stel jou voor dat jy verkoopsverslae vir verskeie streke het met dieselfde produkte en in dieselfde formaat. Jy wil verkoopsyfers vir 'n spesifieke streek vind:
As jy net twee sulke verslae het, dan kan jy 'n skandelik eenvoudige formule met funksies gebruik VPR и IF (IF) om die verlangde verslag te kies om te soek:
=VLOOKUP($D$2,IF($D3="FL",FL_Sales,CA_Sales),2,FALSE)
=ВПР($D$2;ЕСЛИ($D3="FL";FL_Sales;CA_Sales);2;ЛОЖЬ)
waar:
- $D $2 is 'n sel wat die naam van die produk bevat. Let daarop dat ons absolute verwysings hier gebruik om te verhoed dat die opsoekwaarde verander word wanneer die formule na ander selle gekopieer word.
- $D3 is 'n sel met die naam van die streek. Ons gebruik 'n absolute kolomverwysing en 'n relatiewe ryverwysing omdat ons beplan om die formule na ander selle in dieselfde kolom te kopieer.
- FL_Sales и CA_Verkope – die name van die tabelle (of benoemde reekse) wat die ooreenstemmende verkoopsverslae bevat. Jy kan natuurlik die gewone velname en selreeksverwysings gebruik, byvoorbeeld 'FL Sheet'!$A$3:$B$10, maar benoemde reekse is baie geriefliker.
Wanneer daar egter baie sulke tabelle is, sal die funksie IF is nie die beste oplossing nie. In plaas daarvan kan jy die funksie gebruik INDIREKTE (INDIREKTE) om die verlangde soekreeks terug te gee.
Soos u waarskynlik weet, is die funksie INDIREKTE word gebruik om 'n skakel terug te gee wat deur 'n teksstring gegee word, wat presies is wat ons nou nodig het. Vervang dus met vrymoedigheid in die formule hierbo die uitdrukking met die funksie IF om met funksie te skakel INDIREKTE. Hier is 'n kombinasie VPR и INDIREKTE werk uitstekend met:
=VLOOKUP($D$2,INDIRECT($D3&"_Sales"),2,FALSE)
=ВПР($D$2;ДВССЫЛ($D3&"_Sales");2;ЛОЖЬ)
waar:
- $D $2 – dit is 'n sel met die naam van die produk, dit is onveranderd as gevolg van die absolute skakel.
- $D3 is die sel wat die eerste deel van die streeknaam bevat. In ons voorbeeld, dit FL.
- _Verkope – die gemeenskaplike deel van die naam van alle benoemde reekse of tabelle. Wanneer dit gekombineer word met die waarde in sel D3, vorm dit die volledig gekwalifiseerde naam van die vereiste reeks. Hieronder is 'n paar besonderhede vir diegene wat nuut is by die funksie INDIREKTE.
Hoe INDIREKTE en VLOOKUP werk
Laat ek jou eers die sintaksis van die funksie herinner INDIREKTE (INDIREK):
INDIRECT(ref_text,[a1])
ДВССЫЛ(ссылка_на_текст;[a1])
Die eerste argument kan 'n selverwysing (A1- of R1C1-styl), 'n reeksnaam of 'n teksstring wees. Die tweede argument bepaal watter skakelstyl in die eerste argument vervat is:
- A1as die argument is WARE KODE (WAAR) of nie gespesifiseer nie;
- R1C1Indien FAS E (ONWAAR).
In ons geval het die skakel die styl A1, sodat jy die tweede argument kan weglaat en op die eerste kan fokus.
Kom ons keer dus terug na ons verkoopsverslae. As jy onthou, dan is elke verslag 'n aparte tabel wat op 'n aparte blad geleë is. Vir die formule om korrek te werk, moet jy jou tabelle (of reekse) benoem en alle name moet 'n gemeenskaplike deel hê. Byvoorbeeld, soos volg: CA_Verkope, FL_Verkope, TX_Verkope en so aan. Soos u kan sien, is "_Sales" teenwoordig in al die name.
funksie INDIREKTE verbind die waarde in kolom D en die teksstring “_Sales”, en vertel daardeur VPR in watter tabel om te soek. As sel D3 die waarde "FL" bevat, sal die formule die tabel deursoek FL_Verkope, indien “CA” – in die tabel CA_Verkope en so aan.
Die resultaat van die funksies VPR и INDIREKTE sal die volgende wees:
As die data in verskillende Excel-boeke geleë is, moet jy die naam van die boek voor die genoemde reeks byvoeg, byvoorbeeld:
=VLOOKUP($D$2,INDIRECT($D3&"Workbook1!_Sales"),2,FALSE)
=ВПР($D$2;ДВССЫЛ($D3&"Workbook1!_Sales");2;ЛОЖЬ)
As die funksie INDIREKTE verwys na 'n ander werkboek, daardie werkboek moet oop wees. As dit gesluit is, sal die funksie 'n fout rapporteer. #REF! (#SSYL!).