Contents [show]
Gister in die marathon 30 Excel-funksies in 30 dae ons het die elemente van die skikking gevind deur die funksie te gebruik MATCH (SOEK) en gevind dat dit uitstekend werk in 'n span met ander kenmerke soos VLOOKUP (VLOOKUP) en INDEKS (INDEKS).
Op die 20ste dag van ons marathon sal ons die studie van die funksie wy ADRES (ADRES). Dit gee die seladres in teksformaat terug deur die ry- en kolomnommer te gebruik. Het ons hierdie adres nodig? Kan dieselfde met ander funksies gedoen word?
Kom ons kyk na die besonderhede van die funksie ADRES (ADRES) en bestudeer voorbeelde van werk daarmee. As jy bykomende inligting of voorbeelde het, deel dit asseblief in die kommentaar.
Funksie 20: ADRES
funksie ADRES (ADRES) gee 'n selverwysing as teks op grond van die ry- en kolomnommer. Dit kan 'n absolute of relatiewe skakelstyladres terugstuur. A1 or R1C1. Daarbenewens kan die bladnaam by die resultaat ingesluit word.
Hoe kan die ADRES-funksie gebruik word?
funksie ADRES (ADRES) kan die adres van 'n sel terugstuur, of saam met ander funksies werk na:
- Kry seladres gegewe ry- en kolomnommer.
- Vind selwaarde deur die ry- en kolomnommer te ken.
- Gee die adres van die sel met die grootste waarde terug.
Sintaksis ADDRESS (ADDRESS)
funksie ADRES (ADRES) het die volgende sintaksis:
ADDRESS(row_num,column_num,[abs_num],[a1],[sheet_text])
АДРЕС(номер_строки;номер_столбца;[тип_ссылки];[а1];[имя_листа])
- abs_getal (skakel_tipe) – indien gelyk 1 of glad nie gespesifiseer nie, sal die funksie die absolute adres ($A$1) terugstuur. Gebruik die waarde om die relatiewe adres (A1) te kry 4. Ander opsies: 2=A$1, 3=$A1.
- a1 – indien TRUE (TRUE) of glad nie gespesifiseer nie, gee die funksie 'n verwysing in die styl terug A1, as ONWAAR (ONWAAR), dan in styl R1C1.
- Sheet_teks (bladnaam) – die naam van die blad kan gespesifiseer word as jy dit wil sien in die resultaat wat deur die funksie teruggestuur word.
Traps ADRES
funksie ADRES (ADRES) gee slegs die adres van die sel as 'n teksstring terug. As jy die waarde van 'n sel benodig, gebruik dit as 'n funksie-argument INDIREKTE (INDIREKTE) of gebruik een van die alternatiewe formules wat in Voorbeeld 2 getoon word.
Voorbeeld 1: Kry seladres volgens ry- en kolomnommer
Gebruik van funksies ADRES (ADRES) Jy kan die seladres as teks kry deur die ry- en kolomnommer te gebruik. As jy slegs hierdie twee argumente invoer, sal die resultaat 'n absolute adres wees wat in skakelstyl geskryf is A1.
=ADDRESS($C$2,$C$3)
=АДРЕС($C$2;$C$3)
Absoluut of relatief
As jy nie 'n argumentwaarde spesifiseer nie abs_getal (verwysingstipe) in 'n formule, is die resultaat 'n absolute verwysing.
Om die adres as 'n relatiewe skakel te sien, kan jy dit as 'n argument vervang abs_getal (verwysingstipe) waarde 4.
=ADDRESS($C$2,$C$3,4)
=АДРЕС($C$2;$C$3;4)
A1 of R1C1
Om skakels te styl R1C1, in plaas van die verstekstyl A1, Jy moet ONWAAR vir die argument spesifiseer a1.
=ADDRESS($C$2,$C$3,1,FALSE)
=АДРЕС($C$2;$C$3;1;ЛОЖЬ)
Bladnaam
Die laaste argument is die naam van die blad. As jy hierdie naam in die resultaat benodig, spesifiseer dit as 'n argument bladteks (bladnaam).
=ADDRESS($C$2,$C$3,1,TRUE,"Ex02")
=АДРЕС($C$2;$C$3;1;ИСТИНА;"Ex02")
Voorbeeld 2: Vind selwaarde deur ry- en kolomnommer te gebruik
funksie ADRES (ADRES) gee die adres van die sel terug as teks, nie as 'n geldige skakel nie. As jy die waarde van 'n sel moet kry, kan jy die resultaat gebruik wat deur die funksie teruggestuur word ADRES (ADRES), as argument vir INDIREKTE (INDIREKTE). Ons sal die funksie bestudeer INDIREKTE (INDIREK) later in die marathon 30 Excel-funksies in 30 dae.
=INDIRECT(ADDRESS(C2,C3))
=ДВССЫЛ(АДРЕС(C2;C3))
funksie INDIREKTE (INDIREKTE) kan sonder die funksie werk ADRES (ADRES). Hier is hoe jy kan, met behulp van die aaneenskakelingsoperateur "&“, blind die verlangde adres in die styl R1C1 en as gevolg daarvan kry die waarde van die sel:
=INDIRECT("R"&C2&"C"&C3,FALSE)
=ДВССЫЛ("R"&C2&"C"&C3;ЛОЖЬ)
funksie INDEKS (INDEX) kan ook die waarde van 'n sel terugstuur as 'n ry- en kolomnommer gespesifiseer is:
=INDEX(1:5000,C2,C3)
=ИНДЕКС(1:5000;C2;C3)
1:5000 is die eerste 5000 rye van 'n Excel-blad.
Voorbeeld 3: Gee die adres van die sel met die maksimum waarde terug
In hierdie voorbeeld sal ons die sel met die maksimum waarde vind en die funksie gebruik ADRES (ADRES) om haar adres te kry.
funksie MAX (MAX) vind die maksimum getal in kolom C.
=MAX(C3:C8)
=МАКС(C3:C8)
Volgende kom die funksie ADRES (ADRES) gekombineer met MATCH (MATCH), wat die reëlnommer vind, en KOLOM (KOLOM), wat die kolomnommer spesifiseer.
=ADDRESS(MATCH(F3,C:C,0),COLUMN(C2))
=АДРЕС(ПОИСКПОЗ(F3;C:C;0);СТОЛБЕЦ(C2))